Script to change the Skype for Business taskbar icon back to Lync and vice versa

I have created 2 scripts for those wishing to switch back to the Lync 2013 taskbar icon after the Skype for Business update (kb2889923)

 Both are VBscript and require administrative privileges to run.

To change back to the Lync 2013 taskbar icon:

SfBtoLyncTaskbarIcon.vbs

'*********************************************
'***                                       ***
'*** Created by Andrew Cleland             ***
'***                                       ***
'*** Version 1.0 - 10/06/2015              ***
'***                                       ***
'*********************************************

Set objFS = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Wscript.Shell")

strLyncInstallPath = objShell.RegRead("HKLM\SOFTWARE\Microsoft\Office\15.0\Lync\InstallationDirectory")
strOffice2013ShortCutPath = objShell.SpecialFolders("AllUsersStartMenu") & "\Programs\Microsoft Office 2013"

strLyncShortCut = strOffice2013ShortCutPath & "\Lync 2013.lnk"
strSfBShortCut = strOffice2013ShortCutPath & "\Skype for Business 2015.lnk"

if (objFS.FileExists(strSfBShortCut)) then
	objFS.MoveFile strSfBShortCut, strLyncInstallPath
end if

if not (objFS.FileExists(strLyncShortCut)) then
	Set objLyncShortcut = objShell.CreateShortCut(strLyncShortCut)
	objLyncShortcut.TargetPath = strLyncInstallPath & "\lync.exe"
	objLyncShortcut.Description = "Connect with people everywhere through voice and video calls, Lync Meetings, and IM."
	objLyncShortcut.IconLocation = strLyncInstallPath & "\lync.exe, 64"
	objLyncShortcut.WorkingDirectory = strLyncInstallPath
	objLyncShortcut.Save
	Set objLyncShortcut = Nothing
end if

Set objShell = Nothing
Set objFS = Nothing

And to revert back to the Skype for Business taskbar icon:

LyncToSfBTaskbarIcon.vbs

'*********************************************
'***                                       ***
'*** Created by Andrew Cleland             ***
'***                                       ***
'*** Version 1.0 - 10/06/2015              ***
'***                                       ***
'*********************************************

Set objFS = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Wscript.Shell")

strLyncInstallPath = objShell.RegRead("HKLM\SOFTWARE\Microsoft\Office\15.0\Lync\InstallationDirectory")
strOffice2013ShortCutPath = objShell.SpecialFolders("AllUsersStartMenu") & "\Programs\Microsoft Office 2013"

strLyncShortCut = strOffice2013ShortCutPath & "\Lync 2013.lnk"
strSfBShortCut = strLyncInstallPath & "\Skype for Business 2015.lnk"

if (objFS.FileExists(strSfBShortCut)) then
	objFS.CopyFile strSfBShortCut, strOffice2013ShortCutPath & "\"
	if (objFS.FileExists(strLyncShortCut)) then
		objFS.MoveFile strLyncShortCut, strLyncInstallPath
	end if
end if


Set objShell = Nothing
Set objFS = Nothing